acceder a Webservice con certificado de cliente

[iMia]

bueno.. después de media mañana buscando y releyendo....
he encontrado esto en el propio foro... http://www.clubdelphi.com/foros/show...postcount=1198
Ahí lo hace... pero usando capicom...no me gusta mucho, pero por ahora es lo que hay...ç

Saludos..

[iMia]

Como la respuesta era de 2017 y ha llovido un poquito desde entonces, CAPICOM debe haber cambiado de versión y hay cosas que no funcionan.......

Concretamente:

- ya no existe el tipo PCCERT_CONTEXT,
- la excepcion EOleSysError no existe
- ni la función InternetSetOption(

[Garada]

Empezado por iMia

Como la respuesta era de 2017 y ha llovido un poquito desde entonces, CAPICOM debe haber cambiado de versión y hay cosas que no funcionan.......

Concretamente, ya no existe el tipo PCCERT_CONTEXT, ni la función InternetSetOption(

InernetSetOpcion está en WinInet

[iMia]

Empezado por Garada

InernetSetOpcion está en WinInet

Me faltaba el uses de System.Win.ComObj para el EOleSysError

y el uses del WinInet para el InternetSetOption como tu bien has apuntado!


Gracias!

[iMia]

Funcionando....
el último problema lo tenia en la estructura CERT_CONTEXT, pero solo la necesitaba para darle una dimensión máxima, por lo que la he fijado a 1024, más que de sobras para el certificado.
Con eso el WS contesta perfectamente...

gracias a tod@s...

P.D.: Después de unos 4 o 5 años sin hacer nada de WS en Delphi (ni de delphi en 2 años...) me he tenido que poner al dia rapidito...

[Garada]

CERT_CONTEXT tiene un tamaño fijo, usa SizeOf(CERT_CONTEXT) me imagino que es para la llamada a InternetSetOption. Fíjate en los ejemplos.

Por cierto, el que dejé no usa Capicom sino WinCrypt y te ahorras estar instalandola.

[Garada]

Yo lo he hecho con Delphi 2010 con llamadas a la biblioteca WinCrypt.
Cargas el archivo PFX con el certificado (o lo puedes tener almacenado en la base de datos o en un recurso) a un almacén de certificados temporal, extraes el certificado y lo añades al WebService.

Código Delphi [-]
procedure HTTPRIOHTTPWebNode1BeforePost(const HTTPReqResp: THTTPReqResp; Data: Pointer);

  procedure CheckError(Puntero: Pointer);
  begin
    if not Assigned(Puntero) then
      RaiseLastOSError;
  end;

const
  INTERNET_OPTION_CLIENT_CERT_CONTEXT = 84;
  Pass = 'LaContraseña';
var
  pStore: HCERTSTORE;
  pCert: PCERT_CONTEXT;
  DataBlob: CRYPT_DATA_BLOB;
  PFX: AnsiString;
begin
  pStore := nil;
  pCert := nil;

  PFX := FuncionQueLeaElFicheroPFX;

  try
    DataBlob.cbData := Length(PFX);
    DataBlob.pbData := @PFX[1];

    // Almacen temporal con el contenido del PFX
    pStore := PFXImportCertStore(DataBlob, PWideChar(Pass), {PKCS12_NO_PERSIST_KEY + }PKCS12_INCLUDE_EXTENDED_PROPERTIES);
    CheckError(pStore);

    // Buscar un certificado con clave privada
    // Solo debería haber uno
    pCert := CertFindCertificateInStore(pStore,
                                        X509_ASN_ENCODING,
                                        0,
                                        CERT_FIND_HAS_PRIVATE_KEY, //CERT_FIND_ANY,
                                        nil,
                                        nil);
    CheckError(pCert);

    // Pasarlo al servicio
    InternetSetOption(Data, INTERNET_OPTION_CLIENT_CERT_CONTEXT, pCert, SizeOf(CERT_CONTEXT));
  finally
    if Assigned(pCert) then
      CertFreeCertificateContext(pCert);

    if Assigned(pStore) then
      CertCloseStore(pStore, 0);
  end;
end;

Para las declaraciones de la biblioteca uso JwaWinCrypt y añado la declaración de PFXImportCertStore.
En Delphi 2010 sólo parte de las declaraciones están en CertHelper por eso prefiero las del JEDI, puede que en versiones más modernas esté más completa.

Código Delphi [-]
function PFXImportCertStore(var pPFX: CRYPT_DATA_BLOB;
                            szPassword: LPCWSTR;
                            dwFlags: DWORD): HCERTSTORE; stdcall; external 'Crypt32.dll';