Lines

[roman]

Empezado por Picard

alguna sugerencia?

Las sugerencias que puedo darte no sé si sirvan a tus propósitos y además ten en cuenta que están enfocadas a Delphi aunque no creo que presente problemas trasladarlas a C++.

En primer lugar quizá podrías considerar otro tipo de superficie como un PaintBox en lugar de un Panel ya que este último carece de un Canvas para dibujar.

Si es forzoso el uso de una Panel entonces tendrás que crearle un Canvas. Para ello declara una variable PanelCanvas de tipo TCanvas misma que inicializas en algún lugar antes de comenzar a dibujar, por ejemplo en el constructor del formulario:

Código Delphi [-]
PanelCanvas := TPanel.Create;
PanelCanvas.Handle := GetDC(Panel.Handle);

Y no olvide destruirla con PanelCanvas.Free, por ejemplo en el destructor del formulario.

Ahora vamos a suponer que Center es una variable de tipo TPoint con las coordenadas desde donde parte la línea. Puedes inicializar Center con las coordenadas del centro de la pantalla aunque sospecho que más bien te refieres al centro del panel. Si realmente es el centro de la pantalla entonces deberás convertir las coordenadas absolutas a coordenadas relativas al panel:

Código Delphi [-]
Center := Point(Screen.Width div 2, Screen.Height div 2);
Center := Panel.ScreenToClient(Center);

Ahora bien, para dibujar una línea dispones de varios métodos del objeto Canvas como LineTo y PolyLine. La parte problemática está en cómo mover la línea ya que tienes que ir borrando la posicíon anterior conforme desplazas el puntero. Desafortunadamente esto no es fácil ya que una vez que dibujas algo sobre el canvas pierdes toda la información de lo que tenías abajo y "borrar la línea" significa que debes reemplazar justamente lo que había abajo antes de dibujarla.

La manera más fácil de lograr un efecto parecido es utilizando la técnica del XOR. Dibujar en modo XOR significa que el color de la pluma se combina con el color del canvas haciendo una operación xor de bits. Al repetir la operación xor se regresa a los bits originales, esto es, al color que originalmente haya habido.

La desventaja de este método es que no tienes control sobre el color de la línea que se va dibujando ya que depende del color del fondo.

Para implementar esto en el evento OnMouseMove lo único que tienes que hacer es, primero dibujar la línea anterior para borrarla y luego dibujar la línea en la nueva posición:

Código Delphi [-]
PanelCanvas.Polyline([Center, EndPoint]);
EndPoint := Point(X,Y);
PanelCanvas.Polyline([Center, EndPoint]);

donde EndPoint es una variable de tipo Point que va manteniendo el punto final de la línea y que conviene que inicialices a lo mismo que Center.

Algo muy común- que te pongo aquí a manera de resumen -es ir trazando la línea sólo cuando el botón del ratón está oprimido y dibujar la línea en su posición final (ahora sí con el color que se desee) al soltar el botón:

Código Delphi [-]
{
  Comenzamos el trazado tomando como punto
  base el punto donde se localiza el ratón
}
procedure PanelMouseDown(...);
begin
  if Button = mbLeft then
  begin
    MouseDown := true;

    PanelCanvas.Pen.Color := clWhite;
    PanelCanvas.Pen.Mode := pmXor;

    Center := Point(X, Y);
    EndPoint := Center;
  end;
end;

{
  Si el botón está presionado "movemos"
  la línea hasta el nuevo punto final
}
procedure MouseMove(...);
begin
  if MouseDown then
  begin
    PanelCanvas.Polyline([Center, EndPoint]);
    EndPoint := Point(X, Y);
    PanelCanvas.Polyline([Center, EndPoint]);
  end;
end;

{
  Terminamos el trazado y dibujamos
  la línea en su posición final
}
procedure MouseUp(...);
begin
  MouseDown := false;
  PanelCanvas.Pen.Mode := pmCopy;
  PanelCanvas.Pen.Color := clBlue;
  PanelCanvas.Polyline([Center, EndPoint]);
end;

Aquí MouseDown es una variable booleana para inicar si el botón del ratón está presionado.

// Saludos