Como cargar los un TreeView desde una tabla SQL

[Casimiro Noteví]

Empezado por cloayza

Estimado Diego200519, bienvenido a club delphi...lea la guía de estilo...lo llamaran al orden en breve...

Tiene perdón por ser nuevo
Pero sí, no olvides leer nuestra guía de estilo, gracias.
Y recuerda usar las etiquetas cuando pongas código, por ejemplo:

[bucanero]

hola!,
intentalo con esta rutina

uses 
  System.Generics.Collections;

...

procedure LoadTreeViewFromDataset(TreeView: TTreeView; dataset: TDataSet);
var
  id, parent_id: integer;
  nombre: string;
  parentNode, TreeNode: TTreeNode;
begin
  /// genera una lista temporal de indices para acceder a los nodos por su ID
  with Tdictionary<Integer, TTreeNode>.create do
  try
    dataset.First;
    while not dataset.Eof do begin
      /// -- Aqui lee los datos de la tabla del nodo que se va a crear
      id := dataset.FieldByName('id').AsInteger;
      parent_id := dataset.FieldByName('parent_id').Value;
      nombre := dataset.FieldByName('nombre').Value;
      /// ---

      // comprueba si existe el nodo padre
      if not TryGetValue(parent_id, parentNode) then
        parentNode := nil;

      // genera el nuevo nodo
      TreeNode := TreeView.Items.AddChild(parentNode, nombre);
      // inserta un puntero al id de la tabla, por si mas tarde se desea localizar el registro nuevamente
      TreeNode.Data := pointer(id);

      // lo inserta en la lista de indices
      AddOrSetValue(id, TreeNode);
      dataset.next;
    end;
  finally
    /// Libera la lista de indices
    free;
  end;
end;

procedure TForm2.ButtonLeerTreeViewClick(Sender: TObject);
begin
  try
    TreeView1.Items.BeginUpdate;
    FDQuery1.disableControls;
    if not FDQuery1.active then
      FDQuery1.open;
    LoadTreeViewFromDataset(TreeView1, FDQuery1);
  finally
    FDQuery1.close;
    FDQuery1.enableControls;
    TreeView1.Items.endUpdate;
  end;
end;

IMPORTANTE: para no tener problemas con la lectura del arbol desde una consulta SQL es necesario que los resultados se muestren ordenados por el campo padre, ID.

EJEMPLO:

Código SQL [-]
SELECT id, parent_id, nombre
  FROM tabla_arbol
 WHERE id >= parent_id
ORDER BY parent_id, id

[Diego200519]

Buenos días bucanero, me complace decirte que la solución que me has propuesto me funciono , lamento no haber visto tu respuesta antes, pero si, efectivamente es lo que estaba buscando, mil gracias