Ojo con el TimeStamp de Respuesta

[razorxxx]

Empezado por bmfranky

Hola, la hora oficial del gobierno de españa , para todas las paginas oficiales, derivan de la que pones, que a su vez coje la hora del Real Observatorio de la Armada (ROA) que es la que cojemos nosotros, desde la pagina que ellos referencian , no hay forma de capturar la hora, solo esta alli, para que la veas...

Aclarado gracias!

[razorxxx]

Les traigo una pequeña mejora del código de mqm, que permite pasarle el UTC que queramos. Por tanto, independientemente de la fecha, hora y región que tenga el equipo desde el que se ejecuta la aplicación, nos dará siempre la fecha-hora de Internet correcta:

Código Delphi [-]
function TPPRUEBAS.LeerFechaHoraInternet(UTC: Integer): string;
var
   Https: TIdHTTP;
   SSLHandler: TIdSSLIOHandlerSocketOpenSSL;
   Respuesta: string;
   UnixTicks: Int64;
   FechaHora: TDateTime;
begin
     Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', Now); // Formato inicial por defecto
     try
        SSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);
        SSLHandler.SSLOptions.SSLVersions := [sslvTLSv1_2];  // TLS 1.2 es compatible desde Windows 7 SP1 y Server 2008 R2 SP1, y aún no ha sido descatalogado
        SSLHandler.SSLOptions.Mode := sslmClient;
        Https := TIdHTTP.Create(nil);
        Https.IOHandler := SSLHandler;
        Https.Request.Accept := 'text/html';
        Https.Request.UserAgent := 'Mozilla/5.0 (compatible; Delphi)';
        Https.ConnectTimeout := 5000;  // Máximo 5 segundos para establecer la conexión con el servidor
        Https.ReadTimeout := 5000;  // Máximo 5 segundos para obtener la respuesta
        try
           Respuesta := Https.Get('https://www2.roa.es/cgi-bin/horautc');  // Realiza la solicitud a la API del ROA
           UnixTicks := StrToInt64(Trim(Respuesta));  // Si la respuesta viene en formato Unix (ajusta el formato si la API devuelve algo diferente)
           FechaHora := UnixToDateTime(UnixTicks div 1000);  // Divide entre 1000 para convertir milisegundos a segundos
           FechaHora := IncHour(FechaHora, UTC);  // Adaptarlo al huso horario seleccionado en el parámetro UTC: 1 = UTC+1 (Península y Baleares), 0 = UTC+0 (Canarias), etc
           Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', FechaHora);  // Formatear la fecha-hora en el formato aceptado por Veri*Factu
           Consola.Lines.Add('Fecha-hora de internet sincronizada correctamente.');
        except
              on E: Exception do
              begin
                   // En caso de error, retorna la hora local y avisa de ello en la consola
                   Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', Now);
                   Consola.Lines.Add('No se pudo sincronizar la fecha-hora de internet. Se muestra la fecha-hora del equipo.');
              end;
        end;
     finally
            If Assigned(Https) Then Https.Free;
            If Assigned(SSLHandler) Then SSLHandler.Free;
     end;
end;

[razorxxx]

Estuve intentando hacer la función anterior con TRESTClient, pero al ejecutar la petición me da el error 403 forbidden:

Código Delphi [-]
RESTClient.Authenticator := nil;
RESTClient.BaseURL := 'https://www2.roa.es/cgi-bin/';
RESTClient.ContentType := 'text/html; charset=UTF-8';
Request.Resource := 'horautc';
Request.Method := TRESTRequestMethod.rmGET;
Try
   Request.Execute;
Except
   on E: Exception do
   Begin
    Consola.Lines.Add('Error en la petición "' + Request.Resource + '": ' + E.ClassName + ' - ' + E.Message);
    Result := FALSE;
    EXIT;
   End;
End;

¿Alguien tiene idea de cómo hacer que funcione con TRESTClient? Esto nos ahorraría tener que usar las librerías Openssl.

[razorxxx]

Lo conseguí con objetos TNetHTTPClient:

Código Delphi [-]
function TPPRUEBAS.LeerFechaHoraInternet(UTC: Integer): string;
var
   UnixTicks: Int64;
   FechaHora: TDateTime;
   HttpClient: TNetHTTPClient;
   HttpResponse: IHTTPResponse;
begin
     Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', Now); // Formato inicial por defecto
     Try
        HttpClient := TNetHTTPClient.Create(nil);
        Try
           // Ejecutar la solicitud
           HttpResponse := HttpClient.Get('https://www2.roa.es/cgi-bin/horautc');  // Realizar la solicitud a la API del ROA
           If HttpResponse.StatusCode = 200 Then
           Begin
                UnixTicks := StrToInt64(Trim(HttpResponse.ContentAsString));  // Si la respuesta viene en formato Unix (ajusta el formato si la API devuelve algo diferente)
                FechaHora := UnixToDateTime(UnixTicks div 1000);  // Divide entre 1000 para convertir milisegundos a segundos
                FechaHora := IncHour(FechaHora, UTC);  // Adaptarlo al huso horario indicado en el parámetro UTC: 1 = UTC+1 (Península y Baleares), 0 = UTC+0 (Canarias), etc
                Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', FechaHora);  // Formatear la fecha-hora en el formato aceptado por Veri*Factu
                Consola.Lines.Add('Fecha-hora de internet sincronizada correctamente.');
           End
           Else
               Consola.Lines.Add('Error: ' + HttpResponse.StatusCode.ToString + ' ' + HttpResponse.StatusText);
        Except
              on E: Exception do
              Begin
                   // En caso de error, retorna la hora local y avisa de ello en la consola
                   Result := FormatDateTime('yyyy-mm-dd"T"hh:nn:ss"Z"', Now);
                   Consola.Lines.Add('No se pudo sincronizar la fecha-hora de internet. Se muestra la fecha-hora del equipo.');
              End;
        End;
     Finally
            If Assigned(HttpClient) Then HttpClient.Free;
     End;
end;

Acordarse de poner en el uses: System.Net.HttpClient, System.Net.URLClient, System.Net.HttpClientComponent

[Neftali [Germán.Estévez]]

Actualizado el mensaje #2 que recopila códigos con este hilo.