¿Convertir los caracteres ASCII del ClientSocket.Socket.ReceiveText?

[[Crandel]]

yo me equivoque, cambia la linea

Código Delphi [-]
Lineas.Add(AdjustLineBreaks(Socket.ReceiveText));

por

Código Delphi [-]
Lineas.AddStrings(AdjustLineBreaks(Socket.ReceiveText));

te estaba agregando una sóla linea, por eso el error.

[Kamikaze]

Hola otra vez!!!

¿Tendría que quedar más o menos asi?

Es que me sale un error:

"Incompatible types: 'TStrings' and 'String' "

Código PHP:

procedure TCliente_Ogame.ClientSocket2Read(Sender: TObject;
  Socket: TCustomWinSocket);
var
Lineas: TStringList;
begin
   Lineas := TStringList.Create;
   Lineas.AddStrings(AdjustLineBreaks(Socket.ReceiveText));
   Edit1.Text := Lineas.Strings[13];
end; 


P.D.: Y pensaba que se solucinaría facil todo este problema......

[delphi.com.ar]

Empezado por Crandel

yo me equivoque, cambia la linea

Código Delphi [-]
Lineas.Add(AdjustLineBreaks(Socket.ReceiveText));

por

Código Delphi [-]
Lineas.AddStrings(AdjustLineBreaks(Socket.ReceiveText));

te estaba agregando una sóla linea, por eso el error.

Mmmmm... AddStrings requiere que el parámetro pasado sea un TStrings, por lo que Add es el método apropiado para el resultado de la función AdjustLineBreaks.

[Mick]

Solo comentar que usar AdjustLineBreaks antes de asignar los
textos a un TStrings es marear la perdiz, una perdida de ciclos
de cpu ya que no es necesario.
Un objeto TStrings o derivado de él como un TStringList
o el mismo Lines de un TMemo, entiende perfectamente y
separa las lineas de los textos que tengan solo el
caracter #10 o solo el caracter #13.
De modo que basta asignar el contenido al
TStrings (con Add por ejemplo) y listo.

Saludos

[[Crandel]]

El problema es que con Add, lo agrega en una sóla linea a todo el texto.

El memo lo reconoce perfectamente, pero no se porque el StringList no.

Dentro de un ratito lo pruebo y te comento

[delphi.com.ar]

Empezado por Crandel

El problema es que con Add, lo agrega en una sóla linea a todo el texto.

Se me ocurren varias formas de hacer esto, una es abusando de la función ExtractStrings:

Código Delphi [-]
var
  S: TStringList;
begin
  S := TStringList.Create;
  try
    ExtractStrings([], [], '1'#13#10'2'#13#10'3'#13#10'4', S);
    ShowMessageFmt('Líneas: %d'#13#10, [S.Count]);
  finally
    S.Free;
  end;

Otra es armando una funcioncita para poder usar AddStrings

Código Delphi [-]
  procedure AddLines(AStrings: TStrings; const AText: string);
  var
    S: TStringList;
  begin
    S := TStringList.Create;
    try
      S.Text := AText;
      AStrings.AddStrings(S);
    finally
      S.Free;
    end;
  end;
begin
  { AStrings es el TStrings que le anexaremos las nuevas líneas }
  AddLines(AStrings, '1'#13#10'2'#13#10'3'#13#10'4');
  ShowMessageFmt('Líneas: %d'#13#10, [AStrings.Count]);
end;

Empezado por Crandel

El memo lo reconoce perfectamente, pero no se porque el StringList no.

Seguramente utilizas la propiedad Lines que es un TString en lugar de Text

Saludos!

[Mick]

Empezado por Crandel

El problema es que con Add, lo agrega en una sóla linea a todo el texto.
Dentro de un ratito lo pruebo y te comento

En lugar de Add, se puede hacer algo tan sencillo como:

List.Text:= List.Text + TextoRecibido.

Aunque esto es computacionalmente mas costoso,
ya que se producen muchas conversiones de cadenas innecesarias.

Es preferible ir concatenando el texto en un String normal, y una vez
recibido todo el texto asignarlo una unica vez al TStringlist con un simple:

List.Text:= TextoRecibidoCompleto;

Tambien se pueden utilizar dos objetos TStringList uno para guardar los
textos parciales recibidos y otro para acumular el total usando AddStrings.

ListParcial.Text:= Socket.ReceiveText;
ListTotal.AddStrings(ListParcial);

Aunque no lo parezca este ultimo metodo (usando 2 strings) es el mas rapido
de todos y el que consume menos memoria (no lo he comprobado en la
practica, pero por la forma en que maneja delphi los strings y stringlists a
priori es el metodo que menos conversiones y reasignaciones de memoria
deberia usar).

Saludos

[[Crandel]]

Bueno KamiKaze,

aca con la ayuda de nuestros amigos delphi.com.ar y Mick, ya tenemos nuestra solución, proba entonces este código final:

Código Delphi [-]
procedure TCliente_Ogame.ClientSocket2Read(Sender: TObject; Socket: TCustomWinSocket);
var
Lineas: TStringList;
begin
   Lineas := TStringList.Create;
   Lineas.Text := Socket.ReceiveText;
   Edit1.Text := Lineas.Strings[13];
end;

Segun te entendí, recibís todo el texto de una sóla vez, o lo haces por partes?, si es por partes puedes probar la última alternativa de Mick.

Termino siendo mas facíl de lo imaginado , lo que es ahogarse en un vaso de agua vacio , tantas vueltas por un simple fin de línea

[Mick]

Solo una pequeñas correcciones, hay que destruir el objeto TStringList al final sino tendremos un memory leak bastante grave, ya que cada vez que se ejecute la funcion se creara un nuevo stringlist que no se destruira al salir de ella.

procedure TCliente_Ogame.ClientSocket2Read(Sender: TObject; Socket: TCustomWinSocket);
var
Lineas: TStringList;
begin
   Lineas := TStringList.Create;
   try
     Lineas.Text := Socket.ReceiveText;
     Edit1.Text := Lineas.Strings[13];
   finally
     Lineas.Free;
   end; 
end;

Si se va a ejecutar muchas veces esta funcion tambien puede ser preferible tener creada con anterioridad el objeto Lineas y no destruirlo nunca, de ese modo nos ahorramos la frecuente creacion y destruccion del objeto.

Tambien seria necesario asegurarse de que existe por lo menos 13 lineas en el texto recibido, si no en el caso de recibir menos datos dara un error al intentar acceder a una linea no existente.

Saludos