¡Malditos componentes!

[ElDuc]

Hola a todos,

Por enésima vez estoy intentando crear un componente, pero como todas las demás veces NO SOY CAPAZ.

El primer problema insalvable con el que me encuentro es que se me hace imposible poner en el icono de la barra de componentes mi propio bitmap, lo he intentado multiples veces, siguiendo distintos tutoriales y siempre me sucede lo mismo: Si mi componente deriva de TLabel mi icono adquiere el bitmap de ese componente y no hay forma humana de poder colocarle mi propio bitmap.

He creado el archivo de recursos siguiendo las pautas del nombre igual que el nombre del archivo .pas del componente y el nombre del archivo gráfico en mayúsculas pero nada.

El otro problema con el que me estrello siempre es que una propiedad colocada en Publised, si es simple Integer, Byte, String, etc la veo en el inspector de objetos, pero si es un Record, por ejemplo

Código Delphi [-]
Type
  TMyProperty=Record
  I:Integer;  
  B:Byte; 
  End;
MyObject=Clss(TLabel)
  Private
  FMyProperty:TMyProperty;
  Function FMyProperty:TMyProperty;
  Procedure PMyProperty(D:TMyProperty);
  Publised
  Property MyProperty:TMyProperty Read FMyProperty Write PMayProperty;
  End;

En este caso yo espero ver en el inspector de objetos el típico desplegable:
+MyProperty
A
B
Pero NO SALE NADA.

Por favor. si podéis, ayudadme a superar esta asignatura pendiente para mi.

Gracias.

[Casimiro Notevi]

Si quieres, sube el fuente o ponlo aquí mismo para que le podamos echar un vistazo

[ElDuc]

Código Delphi [-]
unit _ieApplication;
interface
uses
  SysUtils, Classes, JfMain;
type
  TieData=Record
    A:Integer;
    B:Integer;
    End;
  TieApplication = class(TJfCApplication)
  private
    { Private declarations }
    vieData:TieData;
    Function rieData:TieData;
    Procedure wieData(V:TieData);
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
    Property ieData:TieData Read rieData Write wieData;
  end;
procedure Register;
implementation
Function TieApplication.rieData:TieData;
Begin
Result.A:=vieData.A;
Result.B:=vieData.B;
End;
Procedure TieApplication.wieData(V:TieData);
Begin
vieData.A:=V.A;
vieData.B:=V.B;
End;
procedure Register;
begin
  RegisterComponents('ieCRON', [TieApplication]);
end;
end.

[[coso]]

Hola,
no he mirado al detalle tu codigo, pero te comento un par de cosas:

para hacer una propiedad desplegable, debe ser de una clase derivada de TPersistent

Código Delphi [-]
 
type TDesplegable = class(TPersistent)
    A : integer;
    B : string;
end;
 
type TMiComponente = class(TComponent)
   Desp : TDesplegable;
   public
   constructor Create(AOwner: TComponent); overload; 
   destructor Destroy; overload;
   published
    property Desplegable : TDesplegable read Desp write Desp;
end;
 
constructor TMiComponente.Create(AOwner : TComponent);
begin
    inherited;
    Desplegable := TDesplegable.Create;
end;
 
destructor TMicomponente.Destroy;
begin
    Desplegable.Free;
    inherited;
end;

Algo asi, lo hago de cabeza.
Para usar componentes visuales, deberias heredarlos de TComponent o TPersistent. No se si TJFApplication es la clase padre correcta...
Para usar tu propio bitmap, debes crear un bitmap en el archivo .res relacionado con exactamente el nombre de la clase : TMICOMPONENTE (creo que en la llave MAIN) Despues de un par de vez de recompilar y reinstalar, te aparecera el icono. Si no es asi, borra todos los .dcu y el .dpk relacionado, y vuelve a construirlo.
Algo asi, ya te digo que lo hago de cabeza. Lo mejor siempre es cojer un ejemplo sencillo y ir mirando paso a paso como se hace. Un saludo y a ver si te sirve.

[ElDuc]

Lo del icono ya lo he podido resolver, pero con un archivo *.dcr en lugar del *.res. ALELUYA.

Para la propiedad he intentado lo que tú me has aconsejado y no me compila.

Gracias, de todas formas, si se te ocurre otra idea te la agradeceré.

[[maeyanes]]

Hola...

Para crear los bitmaps que usa Delphi en la paleta de componentes, tienes que crear un archivo .DCR (que es un archivo de recursos).

Para esto creas un archivo en el bloc de notas y lo guardas como NombreUnidadDondeRegistrasElComponente.rc:

TMICOMPONENTE Bitmap archivo.bmp // Este es para la versión 24x24
TMICOMPONENTE16 Bitmap archivo16.bmp // Esta es la versión 16x16
TMICOMPONENTE32 Bitmap archivo32.bmp // Esta es la versión 32x32

Lo compilas con Borland Resource Compiler (brc32.exe):

brc32 -r -foNombreUnidadDondeRegistrasElComponente.dcr NombreUnidadDondeRegistrasElComponente.rc

Y lo agregas a tu proyecto (archivo .dpk):

Código Delphi [-]
package MiPackage;

{$R *.res}
{$R NombreUnidadDondeRegistrasElComponente.dcr}
// ...

Ya con esto cuando compiles e instales el paquete en Delphi, las imagenes se verán en la paleta de componentes, dependiendo del tamaño que tengas configurado mostrarlas (iconos chicos, medianos o grandes, esto último en Delphi 2007 en adelante)...


Saludos...

[[maeyanes]]

Hola...

Empezado por ElDuc

Para la propiedad he intentado lo que tú me has aconsejado y no me compila.

Gracias, de todas formas, si se te ocurre otra idea te la agradeceré.

¿Por qué no te compila? ¿Te muestra algún error? Si es así, por que no nos dices cual es para que te podamos ayudar mejor...


Saludos...

[[coso]]

si, el codigo que puse tiene errores

Código Delphi [-]
constructor TMiComponente.Create(AOwner : TComponent);
begin
    inherited;
    Desp := TDesplegable.Create;
end;

lo mismo en destroy. Saludos.

[ElDuc]

Este es el código completo de la unidad:

Código Delphi [-]
unit _ieApplication;
interface
uses
  SysUtils, Classes, JfMain;
type
  TieData=Class(TPersistent)
    A:Integer;
    B:Integer;
    End;
Type
  TieApplication = class(TJfCApplication)
  private
    { Private declarations }
    vieData:TieData;
    Function rieData:TieData;
    Procedure wieData(V:TieData);
  protected
    { Protected declarations }
  public
    { Public declarations }
    Constructor Create(AOwner:TComponent) Overload;
    Destructor Destroy; Overload;
  published
    { Published declarations }
    Property ieData:TieData Read rieData Write wieData;
  end;
procedure Register;
implementation
Constructor TieApplication.Create(Owner:TComponent);
Begin
Inherited;
vieData:=TieData.Create;
End;
Destructor TieApplication.Destroy;
Begin
ieData.Free;
Inherited;
End;
Function TieApplication.rieData:TieData;
Begin
Result.A:=vieData.A;
Result.B:=vieData.B;
End;
Procedure TieApplication.wieData(V:TieData);
Begin
vieData.A:=V.A;
vieData.B:=V.B;
End;
procedure Register;
begin
  RegisterComponents('ieCRON', [TieApplication]);
end;
end.

Y estos son los errores:
[Error] _ieApplication.pas(10): Published field 'A' not a class nor interface type
[Error] _ieApplication.pas(11): Published field 'B' not a class nor interface type

Yo no sé que quiere decir.

[[coso]]

Hola,

Código Delphi [-]
Destructor TieApplication.Destroy;
Begin
ieData.Free;
Inherited;
End;

aqui estas liberando la propiedad, no la variable, que es vieData.
En cuanto a los errores de compilacion, prueba de colocar las variables de la clase TieData dentro de una llave public, a ver si es eso. Un saludo.

[[maeyanes]]

Hola...

Me parece que el error está en la parte de lectura de la propiedad, esta debería ser tu declaración:

Código Delphi [-]
private
  vieData: TieData;

  procedure wieData(Value: TieData);
published
  property ieData: TieData read vieData write wieData;
end;

implementation

procedure TieApplication.wieData(Value: TieData);
begin
  vieData.A := Value.A;
  vieData.B := Value.B
end;

Saludos...

[ElDuc]

Colegas, muchas gracias por vuestra colaboración, por fin lo he conseguid.

Pongo el código y mis comentarios para revertir en aquellos que, como yo hasta ahora, puedan necesitarlo.

Icono del componente:
Lo he solucionado utilizando un archivo *.DCR en lugar de *.RES.
Ya sabéis, si vuestro archivo de código en el que se declara el componente se llama Componentes.PAS, vuestro paquete de recursos debe llamarse Componentes.DCR (igual que el *.PAS, pero cambiando la extensión) y si dentro del archivo Componentes.PAS hay la declaración de dos componentes Componente1 y Componente2, deberéis crear dos bitmaps de 24x24 pixels con los nombre COMPONENTE1 y COMPONENTE2 (TODO EN MAYÚSCULAS), Lo compilais todo y a correr.

Propiedades desplegables (Conjuntos / Record)
Aqií os pongo el código completo de mi unidad:

Código Delphi [-]
unit _ieApplication;
 
interface
 
uses
  SysUtils, Classes, JfMain;
 
type
  TieData=Class(TPersistent)
    Private
    vA:Integer;
    vB:String;
    Function rA:Integer;
    Procedure wA(Value:Integer);
    Function rB:String;
    Procedure wB(Value:String);
    Published
    // Normalmente no son necesarios estos métodos a no ser que se quiera ejercer
    // algún control, pero esto limitará las posibilidades de los descendientes
    Property A:Integer Read rA Write wA;
    Property B:String Read rB Write wB;
    End;

  TieApplication = class(TJfCApplication)
    private
    { Private declarations }
    vieData:TieData;
    Procedure wieData(V:TieData);
    protected
    { Protected declarations }
    public
    { Public declarations }
    Constructor Create(AOwner:TComponent); Override;
    Destructor Destroy; Override;
    published
    { Published declarations }
    // No me acepta una función de lectura cuando el tipo es una clase,
    // pero no es una limitación muy importante
    Property ieData:TieData Read vieData Write wieData;
  end;
 
procedure Register;
 
implementation
 
Function TieData.rA:Integer;
Begin
Result:=vA;
End;
 
Procedure TieData.wA(Value:Integer);
Begin
vA:=Value;
End;
 
Function TieData.rB:String;
Begin
Result:=vB;
End;
 
Procedure TieData.wB(Value:String);
Begin
vB:=Value;
End;
 
Constructor TieApplication.Create(AOwner:TComponent);
Begin
Inherited Create(AOwner);
vieData:=TieData.Create;
// Default
vieData.A:=123;
vieData.B:='Vacia';
End;
 
Destructor TieApplication.Destroy;
Begin
vieData.Free;
Inherited;
End;
 
Procedure TieApplication.wieData(V:TieData);
Begin
vieData.A:=V.A;
vieData.B:=V.B;
End;
 
procedure Register;
begin
  RegisterComponents('ieCRON', [TieApplication]);
end;
 
end.

Cuando quieres crear un conjunto de propiedades (las que en el inspector de objetos se pueden replegar y desplegar con el icono +desplegar y -replegar)
Debes crear una clase con sus propiedades, como en mi código en el cual creo una propiedad ieData que contiene dos propiedades:
A:Integer y B:String;

Espero que esta información pueda ser de utilidad para los que andéis perdidos como estaba yo.