Encadenar sonidos????

[[seoane]]

Caramba, parece que te leo el pensamiento

[tarco35]

Parece que esto es lo que necesito.... lo pruebo y te confirmo... una cosa... todo el primer codigo descrito es para crear una unidad nueva del proyecto no?

[[seoane]]

Empezado por tarco35

Parece que esto es lo que necesito.... lo pruebo y te confirmo... una cosa... todo el primer codigo descrito es para crear una unidad nueva del proyecto no?

Puedes incluirlo en un unit nueva o dentro de la misma unit. Solo tienes que incluir cada cosa en su sitio, es decir, lo que esta debajo de la clausula type ponerlo debajo de la clausula type de tu unit, lo que esa en la clausula uses en la clausula uses y el resto debajo de la clausula implementation.

[tarco35]

Lo he hecho haciendolo en una unidad y cuando llamo al procedimiento create me da error. lo he decladado asi:

unit UnidadSonidos;

interface

uses Classes,Windows;

type
TSound = class(TThread)
private
FList: TStringList;
FMutex: THandle;
protected
procedure Execute; override;
public
constructor Create;
destructor Destroy; override;
procedure Add(Path: String);
end;


implementation

{ TSound }
uses MMSystem;

y a partir de aqui como tu me has indicado. En la prmera linea del CREATE me da el error de violacion????

[tarco35]

Uso Delphi6 enterprise....(por si sirve de algo)

[[seoane]]

Exactamente ¿que error te da?

Por otra parte a mi me quedaría una unit mas o menos así:

Código Delphi [-]
unit Unit2;

interface

uses Windows, Classes;

type
  TSound = class(TThread)
  private
    FList: TStringList;
    FMutex: THandle;
  protected
    procedure Execute; override;
  public
    constructor Create;
    destructor Destroy; override;
    procedure Add(Path: String);
  end;

implementation

uses mmsystem;

{ TSound }

procedure TSound.Add(Path: String);
begin
  WaitForSingleObject(FMutex, INFINITE);
  try
    FList.Add(Path);
  finally
    ReleaseMutex(FMutex);
  end;
end;

constructor TSound.Create;
begin
  FList:= TStringList.Create;
  FMutex:= CreateMutex(nil,FALSE,nil);
  FreeOnTerminate:= TRUE;
  inherited Create(FALSE);
end;

destructor TSound.Destroy;
begin
  FList.Free;
  CloseHandle(FMutex);
  inherited;
end;

procedure TSound.Execute;
var
  Path: String;
begin
  inherited;
  while not Terminated do
  begin
    WaitForSingleObject(FMutex, INFINITE);
    try
      if FList.Count > 0 then
      begin
        Path:= FList[0];
        FList.Delete(0);
      end else
        Path:= '';
    finally
      ReleaseMutex(FMutex);
    end;
    if Path <> '' then
      PlaySound(PChar(Path),0,SND_FILENAME or SND_SYNC)
    else
      Sleep(10);
  end;
end;

end.

Me compila y no me da error alguno.

[tarco35]

Tal y como acabas de describir tengo la unidad.. y errores de compilacion ninguno, pero cuando realizado la llamada al create me lanza el error ACCESS VIOLATION

[[seoane]]

Estas diciendo que te da un error al ejecutar esta sentencia:

Código Delphi [-]
Sound:= TSound.Create;

Puede parecerte una tontería, pero ¿estas colocando la T delante de Sound?