Random no fiable

[[nlsgarcia]]

bulc,

Empezado por bulc

...Me gustaría saber si la clausula Randomize se debe poner en el evento OnCreate o en el procedimiento mismo...

Empezado por RAD Studio VCL Reference

Randomize initializes the built-in random number generator with a random value (obtained from the system clock). The random number generator should be initialized by making a call to Randomize, or by assigning a value to RandSeed.

Do not combine the call to Randomize in a loop with calls to the Random function. Typically, Randomize is called only once, before all calls to Random

Revisa esta información:

1- System.Randomize Function

2- Randomize

Espero sea útil

Nelson.

[ecfisa]

Hola bulc.

La cantidad de imágenes involucradas, no me genera ningún tipo de problema. En este ejemplo uso 24 imágenes:

Código Delphi [-]
...
implementation

var
  vImage : array of TImage;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: Integer;
begin
  SetLength(vImage, 24);
  for i := 0 to ImageList1.Count-1 do
  begin
    vImage[i] := TImage(FindComponent('Image'+IntToStr(i+1)));
    vImage[i].Picture.Bitmap.Width  := 32;
    vImage[i].Picture.Bitmap.Height := 32;
    ImageList1.GetBitmap(i, vImage[i].Picture.Bitmap );
  end;
  Randomize;
end;

procedure TForm1.btnMergeClick(Sender: TObject);
var
  a,b,i: Integer;
  p: TPoint;
begin
  for i := Low(vImage) to High(vImage) do
  begin
    a   := Random(24);
    b   := Random(24);
    p.X := vImage[a].Left;
    p.Y := vImage[a].Top;
    vImage[a].Left := vImage[b].Left;
    vImage[a].Top  := vImage[b].Top;
    vImage[b].Left := p.X;
    vImage[b].Top  := p.Y;
  end;
end;

Salida:


Saludos

[[nlsgarcia]]

bulc,

Empezado por bulc

...Me gustaría saber si la clausula Randomize se debe poner en el evento OnCreate o en el procedimiento mismo...

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, jpeg, ExtCtrls, Math, StdCtrls;

type
  TForm1 = class(TForm)
    Image1: TImage;
    Image2: TImage;
    Image3: TImage;
    Image4: TImage;
    Image5: TImage;
    Image6: TImage;
    Image7: TImage;
    Image8: TImage;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  Shuffle : Boolean;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
   Image : Array of Integer;
   R1, R2 : Integer;
   P : TPicture;
   i : Integer;

begin

   for i := 0 to ComponentCount - 1 do
      if (FindComponent('Image' + IntToStr(i+1)) is TImage) then
      begin
         SetLength(Image, Length(Image)+1);
         Image[High(Image)] := i;
      end;

   RandSeed := GetTickCount; // Randomize; {Función Equivalente}

   Shuffle := True;

   while Shuffle do
   begin

      Application.ProcessMessages;

      R1 := RandomRange(Low(Image),High(Image)+1); // R1 := Random(High(Image)+1); {Función Equivalente}
      R2 := RandomRange(Low(Image),High(Image)+1); // R2 := Random(High(Image)+1); {Función Equivalente}

      P := TPicture.Create;
      P.Assign(TImage(Components[Image[R1]]).Picture.Graphic);
      TImage(Components[Image[R1]]).Picture.Assign(TImage(Components[Image[R2]]).Picture.Graphic);
      TImage(Components[Image[R2]]).Picture.Assign(P.Graphic);
      P.Free;

      Sleep(100);

   end;

end;

procedure TForm1.Button2Click(Sender: TObject);
begin
   Shuffle := False;
end;

end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32, Cambia de forma aleatoria 8 imágenes contenidas en componentes TImage por medio de las funciones RandSeed y RandomRange, como se muestra en la siguiente imagen:



Nota: El código sugerido funciona análogamente con las funciones Randomize y Random.

Espero sea útil

Nelson.