Formato de Salida de una Imagen

[[seoane]]

Timage no convierte entre formatos gráficos, le da igual la extensión que le pongas al archivo, si tienes cargado un bitmap lo guardara como bitmap, si es un jpeg se guardara como un jpeg. Si quieres guardar en un formato distinto tienes que hacer la conversión tu mismo. Si haces una búsqueda por el foro, o en los trucos, encontraras varias formas de hacer lo que tu quieres.

Yo te voy a dejar un par de métodos, uno que guarda la imagen como Jpeg y otro que cambia el tipo de imagen cargada en el TImage. Puedes usar el que mas te guste.

Código Delphi [-]
uses JPEG;

procedure GuardarComoJpeg(Imagen: TPicture; Filename: string);
var
  Bitmap: TBitmap;
  Jpeg: TJPEGImage;
begin
  Jpeg:= TJpegImage.Create;
  try
    if not (Imagen.Graphic is TBitmap) then
    begin
      Bitmap:= TBitmap.Create;
      try
        Bitmap.Width:= Imagen.Width;
        Bitmap.Height:= Imagen.Height;
        Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
        Jpeg.Assign(Bitmap);
      finally
        Bitmap.Free;
      end;
    end else Jpeg.Assign(Imagen.Bitmap);
    Jpeg.SaveToFile(Filename);
  finally
    Jpeg.Free;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
GuardarComoJpeg(Image1.Picture,'c:\imagen.jpg');

La otra forma es la siguiente:

Código Delphi [-]
uses JPEG;

procedure ABitmap(Imagen: TPicture);
var
  Bitmap: TBitmap;
begin
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
end;

procedure AJpeg(Imagen: TPicture);
var
  Jpeg: TJPEGImage;
begin
  if not (Imagen.Graphic is TJPEGImage) then
  begin
    ABitmap(Imagen);
    Jpeg:= TJPEGImage.Create;
    try
      Jpeg.Assign(Imagen.Bitmap);
      Imagen.Assign(Jpeg);
    finally
      Jpeg.Free;
    end;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
  AJpeg(Image1.Picture);
  image1.Repaint;
  // Una vez convertida la imagen al guardarla lo hara como Jpeg