Delphi y intelhex

[[eduarcol]]

es que el asunto radica , segun lo que entendi la linea que necesitas esta en HexBuf que es de tipo Byte, el asunto es convertirlo a string por eso utilize la funcion que agregue al principio

[[seoane]]

Si lo que quieres es solamente eliminar lo que no son datos de cada linea, podemos usar una función como esta:

Código Delphi [-]
function Strip(Str: String): String;
var
  i,j,k: Integer;
begin
  Result:= EmptyStr;
  Str:= Trim(Str);
  if Copy(Str,1,1) = ':' then
    if TryStrToInt('$' + Copy(Str,2,2),i) then
      if Length(Str) = ((2*i) + 11) then
        if TryStrToInt('$' + Copy(Str,4,4),j) then
          if TryStrToInt('$' + Copy(Str,8,2),k) then
            if k = 0 then
              Result:= Copy(Str,10,2*i);
end;

Y si queremos cargar todo en un memo:

Código Delphi [-]
var
  i: Integer;
  Str: String;
begin
  with TStringList.Create do
  try
    LoadFromFile('d:\test.hex');
    for i:= 0 to Count - 1 do
    begin
      Str:= Strip(Strings[i]);
      if Str <> EmptyStr then
        Memo1.Lines.Add(Str);
    end;
  finally
    Free;
  end;
end;

Por otro lado lo que podemos querer en realidad es obtener todos los bytes que se van a grabar (incluidos los que no aparecen el archivo que yo supongo como ceros) y además ordenados. Eso ya es un poco, solo un poco, mas complicado ¿es eso lo que quieres?

[JoseFco]

"Tolomeo se mudo al Polo Norte"

[[seoane]]

Bueno, siguiendo con mi respuesta anterior:

Código Delphi [-]
type
  TBuffer = array[$0000..$FFFF] of Byte;

// Insertamos la linea de datos en un buffer
function Insertar(Str: String; var Buffer: TBuffer): String;
var
  i,j,k: Integer;
begin
  Result:= EmptyStr;
  Str:= Trim(Str);
  if Copy(Str,1,1) = ':' then
    if TryStrToInt('$' + Copy(Str,2,2),i) then
      if Length(Str) = ((2*i) + 11) then
        if TryStrToInt('$' + Copy(Str,4,4),j) then
          if TryStrToInt('$' + Copy(Str,8,2),k) then
            if k = 0 then
            begin
              Str:= Copy(Str,10,2*i);
              for k:= j to (j + i - 1) do
              begin
                Buffer[k]:= StrToInt('$' + Copy(Str,1,2));
                Delete(Str,1,2);
              end;
            end;
end;


// Aqui leemos el archivo y mostramos la informacion en un memo
var
  i,j: Integer;
  Str: String;
  Buffer: TBuffer;
begin
  Memo1.Clear;
  with TStringList.Create do
  try
    LoadFromFile('d:\test.hex');
    // Llenamos todo el buffer con ceros
    FillChar(Buffer,Sizeof(Buffer),#0);
    // Leemos el archivo linea a linea e insertamos los datos en el buffer
    for i:= 0 to Count - 1 do
      Insertar(Strings[i],Buffer);
    Str:= EmptyStr;
    j:= Sizeof(Buffer) - 1;
    // Buscamos el ultimo dato que no es un cero
    while (Buffer[j] = 0) and (j > 0) do
      dec(j);
    // Mostramos el contenido del buffer en un memo
    for i:= 0 to j do
    begin
      Str:= Str + #32 + IntToHex(Buffer[i],2);
      // 16 bytes por linea
      if ((i+1) mod 16 = 0) then
      begin
        Memo1.Lines.Add(Str);
        Str:= EmptyStr;
      end;
    end;
  finally
    Free;
  end;
end;

Solo quedaría añadir algunas cosillas, como la comprobación de la "suma de comprobación".

[JoseFco]

"Tolomeo se mudo al Polo Norte"

[[seoane]]

Memo1 es el nombre de un memo que debes tener colocado en tu formulario

[JoseFco]

"Tolomeo se mudo al Polo Norte"

[[seoane]]

Creo que no me explique bien, el código no debe escribirse directamente en la unit, se debe encerrar dentro de algún evento como por ejemplo hacer click sobre un botón:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type
  TBuffer = array[$0000..$FFFF] of Byte;

function Insertar(Str: String; var Buffer: TBuffer): String;
var
  i,j,k: Integer;
begin
  Result:= EmptyStr;
  Str:= Trim(Str);
  if Copy(Str,1,1) = ':' then
    if TryStrToInt('$' + Copy(Str,2,2),i) then
      if Length(Str) = ((2*i) + 11) then
        if TryStrToInt('$' + Copy(Str,4,4),j) then
          if TryStrToInt('$' + Copy(Str,8,2),k) then
            if k = 0 then
            begin
              Str:= Copy(Str,10,2*i);
              for k:= j to (j + i - 1) do
              begin
                Buffer[k]:= StrToInt('$' + Copy(Str,1,2));
                Delete(Str,1,2);
              end;
            end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i,j: Integer;
  Str: String;
  Buffer: TBuffer;
begin
  Memo1.Clear;
  with TStringList.Create do
  try
    LoadFromFile('d:\test.hex');
    FillChar(Buffer,Sizeof(Buffer),#0);
    for i:= 0 to Count - 1 do
      Insertar(Strings[i],Buffer);
    Str:= EmptyStr;
    j:= Sizeof(Buffer) - 1;
    while (Buffer[j] = 0) and (j > 0) do
      dec(j);
    for i:= 0 to j do
    begin
      Str:= Str + #32 + IntToHex(Buffer[i],2);
      if ((i+1) mod 16 = 0) then
      begin
        Memo1.Lines.Add(Str);
        Str:= EmptyStr;
      end;
    end;
  finally
    Free;
  end;
end;

end.