Puertos Serie

[mrmanuel]

Hola Ignacio,


Te importaria decirme que coponente es el que utilizastes, porque me he puesto a meterle mano a los "APRO" y eso no hay quien lo entienda, y para colmo, los ejemplos no compilan, siempre le falta alguna libreria o modulo.

PD: Tambien necesito conectar un peso al puerto serie.

Gracias, un saludo.

[Ignacio]

Disculp la demora de la respuesta.

Las pestañas se llaman APRO, APRO Telephony, APRO Fax y APRO State Machine.
El control que usé es ApdComPort de la pestaña APRO. Basé todo en el ejemplo ExComp. Mas tarde te mando el codigo que hice, que no es más que la modificación del ejemplo.

Suerte.

[mrmanuel]

Gracias,

Pruebo lo que me has dicho y te cuento, de todas formas si me puedes enviar lo tuyo, mejos, así me aseguro que funciona correctamente. (Porque para estas cosas soy un poco PEZ).

Muchas gracias.

Un saludo.

[Ignacio]

unit Balanza;

interface

uses
  WinTypes, WinProcs, SysUtils, Messages, Classes, Graphics, Controls,
  Forms, Dialogs, StdCtrls, AdPort, OoMisc, ExtCtrls, Buttons, lmdcompo,
  lmdclass, lmdformA;

type
  TFormBalanza = class(TForm)
    ApdComPort1: TApdComPort;
    Bevel1: TBevel;
    LblPeso: TLabel;
    LblPeso2: TLabel;
    BBcorrecto: TBitBtn;
    BBcancelar: TBitBtn;
    LMDFormFill1: TLMDFormFill;
    procedure ApdComPort1TriggerAvail(CP: TObject; Count: Word);
    procedure FormActivate(Sender: TObject);
  private
    { Private declarations }
    function Valor(SS: string) :Integer;
  public
    { Public declarations }
    Peso:Integer;
    Cadena:String;
  end;

var
  FormBalanza: TFormBalanza;

implementation

{$R *.DFM}

procedure TFormBalanza.ApdComPort1TriggerAvail(CP: TObject; Count: Word);
var
  I : Word;
  C : Char;
  S : String;
begin
  S := '';
  for I := 1 to count do begin
    C := ApdComPort1.GetChar;  {C de carga con un caracter enviado por el puerto COM}
    case C of
      #0..#47 : {Desechar} ;   {Son caracteres no numericos previos al cero}
      #80: {Desechar} ; {La P, en esta balanza me indica el inicio de la cadena que trae el peso}
      #75: {Desechar} ; {La K, en esta balanza me indica el fin de la cadena que trae el peso}
      else  S := S + C; {se almacenan en S solo los caracteres que deseo}
      {De esta manera me queda en S una cadena a mi gusto}
    end;
  end;
  {Tengo una función llamada "Valor" que hace de S un numero que representa
   al peso que arrojó la balanza. Esta señal es enviada por el puerto muchas
   veces por segundo. Pero si cada vez que recibo una nueva, la muestro,
   tendría un efecto de parpadeo que dificultaría la lestura del numero por
   el operador. Para evitarlo muestro solamente si el valor que tengo en
   pantalla es distinto al valor resientemente recibido en S}
  if (Peso<>Valor(s)) and (Valor(s)>=0)then
  begin
    Peso:=Valor(s);
    LblPeso.Caption:=IntToStr(Peso);
    LblPeso2.Caption:=IntToStr(Peso);
  end;
end;

procedure TFormBalanza.FormActivate(Sender: TObject);
begin
  Peso:=0;
  LblPeso.Caption:=IntToStr(Peso);
  LblPeso2.Caption:=IntToStr(Peso);
  ApdComPort1.OutPut := 'ATZ'^M;  {Inicia la lectura del puerto}
end;

function TFormBalanza.Valor(SS: string) :Integer;
var
  i:Integer;
begin
  i:=1;
  if SS='' then
    result:=-1
  else
    Result:=StrToInt(Copy(SS,i,6));
end;

end.

Espero que te sea util. Suerte.