Modificar O Crear Componente Edit

[roman]

spider Ramon

A ver si ya nos ponemos a leer la guía de estilo como te han sugerido. La estás infringiendo.

Por otra parte, como te indica delphi.com.ar, si quieres crear componentes lo mejor es que empieces por leer algo de teoría. Puedes empezar por la misma ayuda de Delphi que trae un capítulo completo dedicado a la creación de componentes o aquí mismo en el Club, en la sección de Manuales podrás encontrar uno escrito por Luis Roche.

// Saludos

[spider_Ramon]

Gracias Roman Y Delphi Com Ar Por Mi Necesas,


Y Voy A Leer En Este Momento Lo Queustedes Me Indican

Una Vez Leido Empiezo La Practica Gracias De Nuevo

[Neftali [Germán.Estévez]]

Aquí tienes un ejemplo para hacerlo sin derivar el componente, programándolo en el form:
http://www.swissdelphicenter.ch/torr...ode.php?id=585

Y si quieres derivar el componente para responder a los eventos de ENTER y EXIT y cambiar el color, pues aquí tienes el código (es de un mensaje anterior que contesté con la misma pregunta):

Código Delphi [-]
 unit EditColor;
 
 interface
 
 uses
   Windows, Messages, SysUtils, Classes, Controls, StdCtrls, GRaphics;
 
 type
   TEditColor = class(TEdit)
   private
     FColorEnter: TColor;
     FColorExit: TColor;
 
     // Redefinimos los mensajes de entrada y salida
     procedure CMExit(var Message: TCMExit); message CM_EXIT;
     procedure CMEnter(var Message: TCMEnter); message CM_ENTER;
   protected
     { Protected declarations }
   public
     { Public declarations }
     constructor Create(AOwner: TComponent); override;
   published
     // Color que queremos al entrar (cuando tiene el foco)
     property ColorEnter:TColor read FColorEnter write FColorEnter default clInfoBk;
     // Color que queremos al salir (cuando no tiene el foco)
     property ColorExit:TColor read FColorExit write FColorExit default clWindow;
   end;
 
 procedure Register;
 
 implementation
 
 // Registrar el componente.
 procedure Register;
 begin
   RegisterComponents('Neftali', [TEditColor]);
 end;
 
 { TEditColor }
 // Interceptamos el mensaje de entrada
 procedure TEditColor.CMEnter(var Message: TCMEnter);
 begin
   inherited;
   Self.Color := Self.FColorEnter;
 end;
 
 // Interceptamos el mensaje de salida
 procedure TEditColor.CMExit(var Message: TCMExit);
 begin
   inherited;
   Self.Color := Self.FColorExit;
 end;
 
 // Constructor (valores iniciales)
 constructor TEditColor.Create(AOwner: TComponent);
 begin
   inherited;
   // Valores iniciales
   Self.FColorEnter := clInfoBk;
   Self.FColorExit := clWindow;
 end;
 
 end.