Ayuda con sonidos

[drakon007]

Hola gente, tengo un problema y necesitaría la ayuda de ustedes. Resulta que estoy haciendo un Piano y pude hacerlo sonar con la función:

Código Delphi [-]
Windows.Beep(Frecuencia, Tiempo)

Pero ahí es donde surge el problema, la cuestión es que con eso solo hago sonar los parlantes internos de la PC, y lo que me gustaría hacer es un procedimiento similar a ese pero para los altavoces principales. La verdad que les agradecería mucho su respuesta, desde ya, Gracias.

[drakon007]

Perdón pero ahi puse "hacer un procedimiento", y lo que en realidad me gustaría saber si puedo utilizar uno incluido en Delphi.

[ecfisa]

Hola drakon007.

Podés usar la funcion sndPlaySound, sobre el uso de la misma te pongo dos links, el tercero explica como ejecutar sonidos mediante la placa de audio.

LINK1
LINK2
LINK3

Espero te ayuden.

Saludos.

[drakon007]

Muchas gracias por tu ayuda, pero ya encontré la solución a mi problema usando este código:

Código Delphi [-]
uses
   ExtCtrls,MMSytem;

procedure MakeSound(Frequency{Hz}, Duration{mSec}, Volume: Integer);
var
  WaveFormatEx: TWaveFormatEx;
  MS: TMemoryStream; 
  i, TempInt, DataCount, RiffCount: integer;
  SoundValue: byte; 
  w: double;
const 
  Mono: Word = $0001;
  SampleRate: Integer = 44100;
  RiffId: string = 'RIFF';
  WaveId: string = 'WAVE';
  FmtId: string = 'fmt ';
  DataId: string = 'data';
begin
  if Frequency > (0.6 * SampleRate) then
  begin
    ShowMessage(Format('Sample rate of %d is too Low to play a tone of %dHz', 
      [SampleRate, Frequency]));
    Exit;
  end;
  with WaveFormatEx do 
  begin
    wFormatTag := WAVE_FORMAT_PCM; 
    nChannels := Mono;
    nSamplesPerSec := SampleRate;
    wBitsPerSample := $0008;
    nBlockAlign := (nChannels * wBitsPerSample) div 8;
    nAvgBytesPerSec := nSamplesPerSec * nBlockAlign;
    cbSize := 0;
  end;
  MS := TMemoryStream.Create;
  with MS do
  begin
     DataCount := (Duration * SampleRate) div 1000;
    RiffCount := Length(WaveId) + Length(FmtId) + SizeOf(DWORD) +
      SizeOf(TWaveFormatEx) + Length(DataId) + SizeOf(DWORD) + DataCount; 

    Write(RiffId[1], 4);
    Write(RiffCount, SizeOf(DWORD));
    Write(WaveId[1], Length(WaveId));
    Write(FmtId[1], Length(FmtId));
    TempInt := SizeOf(TWaveFormatEx);
    Write(TempInt, SizeOf(DWORD));
    Write(WaveFormatEx, SizeOf(TWaveFormatEx));
    Write(DataId[1], Length(DataId));
    Write(DataCount, SizeOf(DWORD));

    w := 2 * Pi * Frequency;
    for i := 0 to DataCount - 1 do
    begin
      SoundValue := 127 + trunc(Volume * sin(i * w / SampleRate));
      Write(SoundValue, SizeOf(Byte));
    end;

    sndPlaySound(MS.Memory, SND_MEMORY or SND_SYNC);
    MS.Free;
  end;
end;